pro ticpos,deglen,pixlen,ticsize,incr,units      ;Compute tic positions
  On_error,2

  minpix = deglen*60./pixlen            ;Arc minute per pixel
  incr = minpix*ticsize                 ;Arc minutes between tics

  if (incr LT 0 ) then sgn = -1 else sgn = 1
  incr = abs(incr)
  if ( incr GE 30 )  then units = 'Degrees' else $
  if ( incr LE 0.5 ) then units = 'Arc Seconds'  $
                     else units = 'Arc Minutes'
;                                        determine increment
  case 1 of 

    incr GE 120.0  : incr =  4.         ;degrees
    incr GE  60.0  : incr =  2.         ;degrees
    incr GE  30.0  : incr =  1.         ;degrees
    incr GT  15.0  : incr = 30.         ;minutes 
    incr GE  10.0  : incr = 15.         ;minutes  
    incr GE   5.0  : incr = 10.         ;minutes
    incr GE   2.0  : incr =  5.         ;minutes
    incr GE   1.0  : incr =  2.         ;minutes
    incr GT   0.5  : incr =  1.         ;minutes
    incr GE   0.25 : incr = 30.         ;seconds
    incr GE   0.16 : incr = 15.         ;seconds
    incr GE   0.08 : incr = 10.         ;seconds
    incr GE   0.04 : incr =  5.         ;seconds
    incr GE   0.02 : incr = 2.           ;seconds
    incr LT   0.02 : incr = 1.           ;seconds
  
  endcase                                         

  if ( units EQ 'Arc Seconds' ) then minpix = minpix*60. else $
  if ( units EQ 'Degrees' )  then minpix = minpix/60.

  ticsize= incr/abs(minpix)                ;determine ticsize
  incr = incr*sgn
 
  return 
  end